{ pkgs, lib, ... }:

{
  imports = [
    ./gnome.nix
    ./kitty.nix
    ./firefox.nix
    ./tools/just.nix
  ];

  home.activation.linkOnlyOfficeFonts = lib.hm.dag.entryAfter [ "writeBoundary" ] ''
    FONT_DIR="/run/current-system/sw/share/X11/fonts"
    USER_FONTS="$HOME/.local/share/fonts"
    NATIVE_TARGET="$HOME/.local/share/onlyoffice/desktopeditors/data/fonts"
    FLATPAK_TARGET="$HOME/.var/app/org.onlyoffice.desktopeditors/data/onlyoffice/desktopeditors/data/fonts"

    if [ -d "$FONT_DIR" ]; then
      for TARGET_DIR in "$USER_FONTS" "$NATIVE_TARGET" "$FLATPAK_TARGET"; do
        $DRY_RUN_CMD mkdir -p "$TARGET_DIR"
        $DRY_RUN_CMD rm -f "$TARGET_DIR/AllFonts.js"* "$TARGET_DIR/fonts_thumbnail"* "$TARGET_DIR/font_selection.bin" "$TARGET_DIR/fonts.log"
        $DRY_RUN_CMD cp -Lf "$FONT_DIR"/*.ttf "$FONT_DIR"/*.otf "$FONT_DIR"/*.ttc "$TARGET_DIR/" 2>/dev/null || true
      done
    fi
  '';

  programs.vscode = {
    enable = true;
    package = pkgs.vscode;
    profiles.default = {
      extensions =
        with pkgs.vscode-extensions;
        [
          bbenoist.nix
          ms-python.python
          dart-code.flutter
        ]
        ++ [
          # OpenCode Go: Copilot Provider - pinned to specific version for reproducibility.
          # This extension is not in nixpkgs, only available from VSCode Marketplace.
          (pkgs.vscode-utils.extensionFromVscodeMarketplace {
            name = "opencode-go-for-copilot";
            publisher = "DenizhanDaklr";
            version = "0.1.18";
            sha256 = "0igdkgv6dra3zpd80lhwymdh216dqn8m8kqwsxh258wyk9fzgfk0";
          })
        ];
    };
  };

  fonts.fontconfig.enable = true;
}